roseen69/shitgame
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

add a lib for rendering text in sdl2 and rules to make in makefile

Browse Source
This commit is contained in:
roseen
2026-01-21 14:45:11 -06:00
parent f3c0aafe2f
commit e7d9c013f4
1754 changed files with 850297 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

48
SDL2_ttf/Xcode/pkg-support/resources/CMake/sdl2_ttf-config-version.cmake Normal file
View File

@@ -0,0 +1,48 @@
# based on the files generated by CMake's write_basic_package_version_file
# SDL2_ttf CMake version configuration file:
# This file is meant to be placed in Resources/CMake of a SDL2_ttf framework
if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_ttf.h")
message(AUTHOR_WARNING "Could not find SDL_ttf.h. This script is meant to be placed in the Resources/CMake directory of SDL2_ttf.framework")
return()
endif()
file(READ "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_ttf.h" _sdl_ttf_h)
string(REGEX MATCH "#define[ \t]+SDL_TTF_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_ttf_h}")
set(_sdl_major "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_TTF_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_ttf_h}")
set(_sdl_minor "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_TTF_PATCHLEVEL[ \t]+([0-9]+)" _sdl_patch_re "${_sdl_ttf_h}")
set(_sdl_patch "${CMAKE_MATCH_1}")
if(_sdl_major_re AND _sdl_minor_re AND _sdl_patch_re)
set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_patch}")
else()
message(AUTHOR_WARNING "Could not extract version from SDL_ttf.h.")
return()
endif()
if(PACKAGE_FIND_VERSION_RANGE)
# Package version must be in the requested version range
if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
endif()
else()
if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
set(PACKAGE_VERSION_EXACT TRUE)
endif()
endif()
endif()
# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
set(PACKAGE_VERSION_UNSUITABLE TRUE)
endif()

39
SDL2_ttf/Xcode/pkg-support/resources/CMake/sdl2_ttf-config.cmake Normal file
View File

@@ -0,0 +1,39 @@
# SDL2_ttf CMake configuration file:
# This file is meant to be placed in Resources/CMake of a SDL2_ttf framework
# INTERFACE_LINK_OPTIONS needs CMake 3.12
cmake_minimum_required(VERSION 3.12)
include(FeatureSummary)
set_package_properties(SDL2_ttf PROPERTIES
URL "https://www.libsdl.org/projects/SDL_ttf/"
DESCRIPTION "Support for TrueType (.ttf) font files with Simple Directmedia Layer"
)
set(SDL2_ttf_FOUND TRUE)
set(SDL2TTF_VENDORED TRUE)
set(SDL2TTF_HARFBUZZ TRUE)
set(SDL2TTF_FREETYPE TRUE)
string(REGEX REPLACE "SDL2_ttf\\.framework.*" "SDL2_ttf.framework" _sdl2ttf_framework_path "${CMAKE_CURRENT_LIST_DIR}")
string(REGEX REPLACE "SDL2_ttf\\.framework.*" "" _sdl2ttf_framework_parent_path "${CMAKE_CURRENT_LIST_DIR}")
# All targets are created, even when some might not be requested though COMPONENTS.
# This is done for compatibility with CMake generated SDL2_ttf-target.cmake files.
if(NOT TARGET SDL2_ttf::SDL2_ttf)
add_library(SDL2_ttf::SDL2_ttf INTERFACE IMPORTED)
set_target_properties(SDL2_ttf::SDL2_ttf
PROPERTIES
INTERFACE_COMPILE_OPTIONS "SHELL:-F \"${_sdl2ttf_framework_parent_path}\""
INTERFACE_INCLUDE_DIRECTORIES "${_sdl2ttf_framework_path}/Headers"
INTERFACE_LINK_OPTIONS "SHELL:-F \"${_sdl2ttf_framework_parent_path}\";SHELL:-framework SDL2_ttf"
COMPATIBLE_INTERFACE_BOOL "SDL2_SHARED"
INTERFACE_SDL2_SHARED "ON"
)
endif()
unset(_sdl2ttf_framework_path)
unset(_sdl2ttf_framework_parent_path)