roseen69/shitgame
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

added new screens and getting ready for networking, looking at SDL_net for cross platfrom networking so i dont have to touch windows

Browse Source
This commit is contained in:
roseen
2026-01-24 19:12:36 -06:00
parent a698c0eb41
commit 3aaf5021cc
468 changed files with 262023 additions and 59 deletions
Download Patch File Download Diff File Expand all files Collapse all files

48
SDL2_net-2.2.0/Xcode/pkg-support/resources/CMake/sdl2_net-config-version.cmake Normal file
View File

@@ -0,0 +1,48 @@
# based on the files generated by CMake's write_basic_package_version_file
# SDL2_net CMake version configuration file:
# This file is meant to be placed in Resources/CMake of a SDL2_net framework
if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_net.h")
message(AUTHOR_WARNING "Could not find SDL_net.h. This script is meant to be placed in the Resources/CMake directory of SDL2_net.framework")
return()
endif()
file(READ "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_net.h" _sdl_net_h)
string(REGEX MATCH "#define[ \t]+SDL_NET_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_net_h}")
set(_sdl_major "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_NET_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_net_h}")
set(_sdl_minor "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_NET_PATCHLEVEL[ \t]+([0-9]+)" _sdl_patch_re "${_sdl_net_h}")
set(_sdl_patch "${CMAKE_MATCH_1}")
if(_sdl_major_re AND _sdl_minor_re AND _sdl_patch_re)
set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_patch}")
else()
message(AUTHOR_WARNING "Could not extract version from SDL_net.h.")
return()
endif()
if(PACKAGE_FIND_VERSION_RANGE)
# Package version must be in the requested version range
if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
endif()
else()
if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
set(PACKAGE_VERSION_EXACT TRUE)
endif()
endif()
endif()
# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
set(PACKAGE_VERSION_UNSUITABLE TRUE)
endif()

32
SDL2_net-2.2.0/Xcode/pkg-support/resources/CMake/sdl2_net-config.cmake Normal file
View File

@@ -0,0 +1,32 @@
# SDL2_net CMake configuration file:
# This file is meant to be placed in Resources/CMake of a SDL2_net framework
# INTERFACE_LINK_OPTIONS needs CMake 3.12
cmake_minimum_required(VERSION 3.12)
include(FeatureSummary)
set_package_properties(SDL2_net PROPERTIES
URL "https://www.libsdl.org/projects/SDL_net/"
DESCRIPTION "SDL_net is an example portable network library for use with SDL."
)
set(SDL2_net_FOUND TRUE)
string(REGEX REPLACE "SDL2_net\\.framework.*" "SDL2_net.framework" _sdl2net_framework_path "${CMAKE_CURRENT_LIST_DIR}")
string(REGEX REPLACE "SDL2_net\\.framework.*" "" _sdl2net_framework_parent_path "${CMAKE_CURRENT_LIST_DIR}")
if(NOT TARGET SDL2_net::SDL2_net)
add_library(SDL2_net::SDL2_net INTERFACE IMPORTED)
set_target_properties(SDL2_net::SDL2_net
PROPERTIES
INTERFACE_COMPILE_OPTIONS "SHELL:-F \"${_sdl2net_framework_parent_path}\""
INTERFACE_INCLUDE_DIRECTORIES "${_sdl2net_framework_path}/Headers"
INTERFACE_LINK_OPTIONS "SHELL:-F \"${_sdl2net_framework_parent_path}\";SHELL:-framework SDL2_net"
COMPATIBLE_INTERFACE_BOOL "SDL2_SHARED"
INTERFACE_SDL2_SHARED "ON"
)
endif()
unset(_sdl2net_framework_path)
unset(_sdl2net_framework_parent_path)