roseen69/shitgame
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

added new screens and getting ready for networking, looking at SDL_net for cross platfrom networking so i dont have to touch windows

Browse Source
This commit is contained in:
roseen
2026-01-24 19:12:36 -06:00
parent a698c0eb41
commit 3aaf5021cc
468 changed files with 262023 additions and 59 deletions
Download Patch File Download Diff File Expand all files Collapse all files

54
SDL2_net-2.2.0/VisualC/pkg-support/cmake/sdl2_net-config-version.cmake Normal file
View File

@@ -0,0 +1,54 @@
# based on the files generated by CMake's write_basic_package_version_file
# SDL2_net CMake version configuration file:
# This file is meant to be placed in a cmake subfolder of SDL2_net-devel-2.x.y-VC
if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../include/SDL_net.h")
message(AUTHOR_WARNING "Could not find SDL_net.h. This script is meant to be placed in a CMake subfolder of SDL2_net-devel-2.x.y-VC")
return()
endif()
file(READ "${CMAKE_CURRENT_LIST_DIR}/../include/SDL_net.h" _sdl_net_h)
string(REGEX MATCH "#define[ \t]+SDL_NET_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_net_h}")
set(_sdl_major "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_NET_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_net_h}")
set(_sdl_minor "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_NET_PATCHLEVEL[ \t]+([0-9]+)" _sdl_patch_re "${_sdl_net_h}")
set(_sdl_patch "${CMAKE_MATCH_1}")
if(_sdl_major_re AND _sdl_minor_re AND _sdl_patch_re)
set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_patch}")
else()
message(AUTHOR_WARNING "Could not extract version from SDL_net.h.")
return()
endif()
if(PACKAGE_FIND_VERSION_RANGE)
# Package version must be in the requested version range
if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
endif()
else()
if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
set(PACKAGE_VERSION_EXACT TRUE)
endif()
endif()
endif()
# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
set(PACKAGE_VERSION_UNSUITABLE TRUE)
endif()
# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
if(NOT (CMAKE_SIZEOF_VOID_P STREQUAL "8" OR CMAKE_SIZEOF_VOID_P STREQUAL "4"))
set(PACKAGE_VERSION "${PACKAGE_VERSION} (32+64bit)")
set(PACKAGE_VERSION_UNSUITABLE TRUE)
endif()

45
SDL2_net-2.2.0/VisualC/pkg-support/cmake/sdl2_net-config.cmake Normal file
View File

@@ -0,0 +1,45 @@
# SDL2_net CMake configuration file:
# This file is meant to be placed in a cmake subfolder of SDL2_net-devel-2.x.y-VC
include(FeatureSummary)
set_package_properties(SDL2_net PROPERTIES
URL "https://www.libsdl.org/projects/SDL_net/"
DESCRIPTION "SDL_net is an example portable network library for use with SDL."
)
cmake_minimum_required(VERSION 3.0)
set(SDL2_net_FOUND TRUE)
if(CMAKE_SIZEOF_VOID_P STREQUAL "4")
set(_sdl_arch_subdir "x86")
elseif(CMAKE_SIZEOF_VOID_P STREQUAL "8")
set(_sdl_arch_subdir "x64")
else()
unset(_sdl_arch_subdir)
set(SDL2_net_FOUND FALSE)
return()
endif()
set(_sdl2net_incdir "${CMAKE_CURRENT_LIST_DIR}/../include")
set(_sdl2net_library "${CMAKE_CURRENT_LIST_DIR}/../lib/${_sdl_arch_subdir}/SDL2_net.lib")
set(_sdl2net_dll "${CMAKE_CURRENT_LIST_DIR}/../lib/${_sdl_arch_subdir}/SDL2_net.dll")
# All targets are created, even when some might not be requested though COMPONENTS.
# This is done for compatibility with CMake generated SDL2_net-target.cmake files.
if(NOT TARGET SDL2_net::SDL2_net)
add_library(SDL2_net::SDL2_net SHARED IMPORTED)
set_target_properties(SDL2_net::SDL2_net
PROPERTIES
INTERFACE_INCLUDE_DIRECTORIES "${_sdl2net_incdir}"
IMPORTED_IMPLIB "${_sdl2net_library}"
IMPORTED_LOCATION "${_sdl2net_dll}"
COMPATIBLE_INTERFACE_BOOL "SDL2_SHARED"
INTERFACE_SDL2_SHARED "ON"
)
endif()
unset(_sdl_arch_subdir)
unset(_sdl2net_incdir)
unset(_sdl2net_library)
unset(_sdl2net_dll)